Questo script invia ad uno specifico indirizzo email un elenco dei documenti di tipo VENDITA, emessi durante il giorno.
E' possibile avviare lo script manualmente (ad esempio inserendolo come icona sul proprio desktop avanzato) oppure ad esempio e' possibile programmarne l'esecuzione automatica ogni sera tramite UTIL / PROCEDURE PERSONALIZZATE:
E' possibile avviare lo script manualmente (ad esempio inserendolo come icona sul proprio desktop avanzato) oppure ad esempio e' possibile programmarne l'esecuzione automatica ogni sera tramite UTIL / PROCEDURE PERSONALIZZATE:
Option Explicit
Dim EmailDestinatario
Dim EmailSubject
Dim EmailText
EmailDestinatario="miaemail@miosito.com"
EmailSubject="READY PRO - Report vendite del " & Rdy.Today()
EmailText="Report vendite del " & Rdy.Today() & " generato alle ore " & FormatDateTime(Now(),vbShortTime)
'================================================================
Dim Documento
Dim ElencoDocumenti
Dim TestoEmail
Dim NumDocumenti
Dim TotDocumenti
ElencoDocumenti=""
NumDocumenti=0
TotDocumenti=0
For Each Documento In Rdy.SearchDocs("SELLING",Rdy.Today(),Rdy.Today())
ElencoDocumenti=ElencoDocumenti & vbCrLf
ElencoDocumenti=ElencoDocumenti & Documento.CustomField(4) & " intestata a " & Documento.Anag.Name & " di " & Rdy.FormatCurrency(Documento.TotalAmount) & " " & Documento.CustomField(88)
NumDocumenti=NumDocumenti+1
TotDocumenti=TotDocumenti+Documento.TotalAmount
Next
If ElencoDocumenti="" Then
EmailText=EmailText & vbCrLf & vbCrLf & "NESSUN MOVIMENTO DI VENDITA IN QUESTA DATA"
Else
EmailText=EmailText & vbCrLf & ElencoDocumenti
EmailText=EmailText & vbCrLf & vbCrLf & "Totale N. " & NumDocumenti & " documenti - " & Rdy.FormatCurrency(TotDocumenti) & " EU"
End If
Rdy.SendEmail EmailDestinatario, EmailSubject, EmailText
Rdy.ShowMessage "Report accodato per l'invio tramite email"
