Inviare tramite email un report con gli articoli creati durante il giorno

Questo script invia ad uno specifico indirizzo email un elenco degli articoli creati durante il giorno (ovvero vengono filtrati in base alla data in cui lo script viene eseguito)

E' possibile avviare lo script manualmente (ad esempio inserendolo come icona sul proprio desktop avanzato) oppure ad esempio e' possibile programmarne l'esecuzione automatica ogni sera tramite UTIL / PROCEDURE PERSONALIZZATE:

Option Explicit
 
Dim EmailDestinatario
Dim EmailSubject
Dim EmailText
 
EmailDestinatario="miaemail@miosito.com"
 
EmailSubject="READY PRO - Report articoli creati del " & Rdy.Today()
EmailText="Report articoli creati del " & Rdy.Today() & " generato alle ore " & FormatDateTime(Now(),vbShortTime)
 
'================================================================
Dim contatore
Dim Articoli
Dim Articolo
Dim ElencoArticoli
 
ElencoArticoli = ""
contatore=0
Set Articoli = Rdy.SearchProducts ( "" , "Id DESC" )
For Each Articolo in Articoli
    If Articolo.RecordDetails.CreationDate=Rdy.Today() Then
         ElencoArticoli = ElencoArticoli & vbCrLf
         ElencoArticoli =ElencoArticoli & Articolo.Code & " - " & Articolo.Name
         contatore=contatore+1
    Else
         Exit For
    End If
Next
Set Articoli = Nothing
Response.Write(contatore)
 
If contatore=0 Then
   EmailText=EmailText & vbCrLf & vbCrLf & "NESSUN ARTICOLO CREATO IN QUESTA DATA"
Else
   EmailText=EmailText & vbCrLf & ElencoArticoli
   EmailText=EmailText & vbCrLf & vbCrLf & "Totale articoli creati N. " & contatore
End If
 
Rdy.SendEmail EmailDestinatario, EmailSubject, EmailText
Rdy.ShowMessage "Report accodato per l'invio tramite email"